Keynote 3

相変わらず QuickTime 7.1 で手こずっています。

まず、dimensions が変更されない（実際は、再保存して再び開くと変更されている）。書き出しで設定ファイルを書き出せない。書き出しで設定を使って書き出すことができない。annotation が設定、変更できない（Automator を使って試してみても駄目）。System Events を使って annotation を取得するもその名前おかしいだろ、って結果が返ってくる。で、以前に書いた text track の日本語の件。

これ、ほんとにまともなソフトウェア？

以上は全て AppleScript から操作するときに出会った不具合です。普通に使っている分にはそこそこ使えます（が、以前より機能や使い勝手が悪くなっている気がするのは気のせい？）。

はやく、QuickTime 7 以前の使い勝手に戻ってほしいものです。

のっけから表題と関係のない話でしたが...Keynote 3。iWork '06 に入っているものです。AppleScript の対応度も少しよくなっています。しかし、なぜにスライドの中にあるテキストやアウトラインや図形や表を操作することができないのでしょう。Pages 2 ではできるのに。Pages 2 で使えるクラスが Keynote でも使えるように...と切に願います（Keynote のスクリプト機能を拡張するプラグインはありますが）。

Keynote の用語説明を見てみましたが、それほどいろんなことができるわけではないみたい。トランジションは設定することができるようになっていますね。そこで iPhoto で選択しているアルバムの中の画像を使ってスライドショーを作るスクリプトなんかを。それぞれの画像に適当にトランジションを設定します。

Script Editor で開く

tell application "iPhoto"
    set curAlbum to a reference to current album
    if (count photos of curAlbum) is 0 then return

    set photoList to image path of photos of curAlbum
    set photoListRef to a reference to photoList
end tell

tell application "Keynote"
    launch
    -- make new slideshow
    set themeList to name of appThemes
    set thisTheme to choose from list themeList
    if thisTheme is false then return
    set thisTheme to thisTheme as Unicode text
    -- other slide size...
    -- {800, 600},{1024,768},{1280,720},{1680,1050},{1920,1080},custom...
    set themeData to {theme:thisTheme, slideSize:{800, 600}}
    set thisSlideshow to make new slideshow at end of slideshows with data themeData

    -- get transitions
    set transitionList to name of appTransitions
    set transitionCount to count transitionList

    tell thisSlideshow
        -- make image slides
        make image slides paths photoListRef with set titles
        delete first slide of thisSlideshow
        set slideCount to count slides
    end tell

    -- apply transition
    repeat with i from 1 to slideCount
        set thisTransition to (some item of transitionList) as Unicode text
        set thisTransition to (a reference to (appTransition thisTransition))
        set appTransition of slideTransition of slide i of thisSlideshow to thisTransition
    end repeat

    -- play slideshow
    start thisSlideshow
end tell

実行すると少しの間なにも起きないのでエラーかと思いますが、出来上がるまで少し待ってください。しかし、Keynote で新規ドキュメントを作る方法の分かりにくいこと。結局のところ AppleScript だけでは全ては完成しません。Pages 2 でもそうなのですが、最終的には自分の手で見映えなどを調整しないといけない。

このような限定的な自動化しかできないので欲求不満に陥っていたり。